globals [ geracao ]
breeds [ sardinhas tubaroes ]
sardinhas-own [ apanhada? ]

to preparar
  ca
  set geracao 0
  ask patches [ set pcolor blue ]
  set-default-shape sardinhas "sardinha"
  create-custom-sardinhas numero-inicial-sardinhas
  [ set color gray
    set size 1.0
    setxy random-float screen-size-x random-float screen-size-y
    set apanhada? false ]
  set-default-shape tubaroes "tubarao"
  create-custom-tubaroes numero-inicial-tubaroes
  [ set color black
    set size 2.0
    setxy random-float screen-size-x random-float screen-size-y ]
  do-plot
end

to executar
  ask sardinhas
  [ movimento
    if competicao?
    [ colisao-sardinhas ]
    reproduzir-sardinhas ]
  ask tubaroes
  [ movimento
    if competicao?
    [ colisao-tubaroes ]
    apanhar-sardinhas
    morte ]
  do-plot
  set geracao geracao + 1
  if (not any? tubaroes) or (not any? sardinhas)
  [ stop ]
end

to movimento
  rt random-float 50 - random-float 50
  forward 1
end

to colisao-sardinhas
  if (any? other-sardinhas-here) and (random-float 100 < competicao-sardinhas)
  [ die ]
end

to colisao-tubaroes
  if (any? other-tubaroes-here) and (random-float 100 < competicao-tubaroes)
  [ die ]
end

to reproduzir-sardinhas
  if random-float 100 < reproducao-sardinhas
  [ hatch 1
    [ rt random-float 360
      forward 1 ] ]
end

to apanhar-sardinhas
  locals [ presa ]
  without-interruption
  [ set presa random-one-of sardinhas-here with [ not apanhada? ]
    if presa != nobody
    [ set apanhada?-of presa true ] ]
  if presa != nobody
  [ ifelse random-float 100 < predacao-sardinhas
    [ ask presa
      [ die ] ]
    [ set apanhada?-of presa false ]
    if random-float 100 < reproducao-tubaroes
    [ hatch 1
      [ rt random-float 360
        forward 1 ] ] ]
end

to morte
  if random-float 100 < mortalidade-tubaroes
  [ die ]
end

to do-plot
  set-current-plot "Populacoes"
  set-current-plot-pen "sardinhas"
  plot count sardinhas
  set-current-plot-pen "tubaroes"
  plot count tubaroes
end

; Versão ICES Copyright 2004, Centro de Física Teórica e Computacional
@#$#@#$#@
GRAPHICS-WINDOW
350
10
688
369
20
20
8.0
1
14
1
1
1

CC-WINDOW
351
373
690
500
Command Center

SLIDER
2
164
178
197
numero-inicial-sardinhas
numero-inicial-sardinhas
0
250
200
1
1
NIL

SLIDER
3
200
178
233
reproducao-sardinhas
reproducao-sardinhas
0
100.0
3.0
0.1
1
%

SLIDER
181
164
348
197
numero-inicial-tubaroes
numero-inicial-tubaroes
0
250
100
1
1
NIL

SLIDER
181
200
348
233
mortalidade-tubaroes
mortalidade-tubaroes
0.0
100.0
5.0
0.1
1
%

BUTTON
8
42
100
75
preparar
preparar
NIL
1
T
OBSERVER
T

BUTTON
102
42
191
75
executar
executar
T
1
T
OBSERVER
T

PLOT
8
314
343
542
Populacoes
geracao
pop.
0.0
100.0
0.0
100.0
true
false
PENS
"sardinhas" 1.0 0 -7566196 true
"tubaroes" 1.0 0 -16777216 true

MONITOR
96
85
174
134
sardinhas
count sardinhas
0
1

MONITOR
177
85
266
134
tubaroes
count tubaroes
0
1

TEXTBOX
8
144
148
163
Parametros Sardinhas

TEXTBOX
186
144
325
163
Parametros Tubaroes

MONITOR
8
85
86
134
geracao
geracao
0
1

SLIDER
4
236
178
269
predacao-sardinhas
predacao-sardinhas
0
100
50.0
0.1
1
%

SLIDER
181
236
348
269
reproducao-tubaroes
reproducao-tubaroes
0
100
40.0
0.1
1
%

SWITCH
196
42
335
75
competicao?
competicao?
0
1
-1000

SLIDER
3
275
178
308
competicao-sardinhas
competicao-sardinhas
0
100
5
1
1
%

SLIDER
181
275
348
308
competicao-tubaroes
competicao-tubaroes
0
100
0
1
1
%

@#$#@#$#@
INTRODUÇÃO
----------
Este modelo simula a coexistência de duas espécies, predadores e presas. A inicialização, execução e paragem de uma simulação faz-se da maneira descrita no módulo BICHOS. Também como nesse módulo, o selector COMPETICAO? activa ou desactiva o efeito de competição pelos mesmos recursos: Quando o selector está "on", uma sardinha ou um tubarão que ocupe um "patch" sobrelotado, isto é, ocupado por mais do que um indivíduo da mesma espécie, tem uma certa probabilidade de morrer. Essa probabilidade é controlada pelos cursores COMPETICAO-SARDINHAS e COMPETICAO-TUBAROES.

Sardinhas e tubarões deslocam-se aleatoriamente na janela gráfica, passando de um "patch" para um dos "patches" vizinhos em cada unidade de tempo. À parte o efeito de competição, a dinâmica de cada uma das populações é regulada pelos efeitos dos encontros predador-presa, e pela natalidade e mortalidade de cada espécie isolada. Para as sardinhas, a taxa de natalidade é regulada no cursor REPRODUCAO-SARDINHAS, e consideramos que a principal causa de mortalidade é serem vítimas dos tubarões. A probabilidade de, dado um encontro, uma sardinha ser comida é regulada no cursor PREDACAO-SARDINHAS.

Os tubarões têm uma taxa de mortalidade regulável com o cursor MORTALIDADE-TUBAROES, e reproduzem-se só se conseguirem caçar. Por isso, a reprodução dos tubarões é condicionada a um encontro predador-presa, e pode ocorrer com uma certa probabilidade, regulável com o cursor REPRODUCAO-TUBAROES. Tal como no módulo BICHOS, a reprodução significa a criação de um novo indivíduo num "patch" vizinho do progenitor.

Existem ainda dois cursores que estipulam a quantidade inicial de indivíduos de cada espécie.

UTILIZAÇÃO
----------
Com o selector COMPETICAO? em "off", este modelo corresponde a uma versão discretizada e espacial do modelo predador-presa de Lotka-Volterra. Os únicos parâmetros do modelo são a taxa de reprodução das sardinhas, a taxa de mortalidade dos tubarões, a probabilidade de que um encontro seja mortal para uma sardinha e a taxa de reprodução dos tubarões dado um encontro. A simulação exibe durante algum tempo as oscilações características do modelo de Lotka-Volterra, no entanto a dinâmica é instável, a amplitude das oscilações aumenta e as flutuações acabam por resultar na extinção de uma das espécies.

Com o selector COMPETICAO? em "on", o modelo usa mais dois parâmetros, que regulam a importância do termo logístico, ou seja, a maneira como a escassez de recursos se manifesta na mortalidade, em cada uma das espécies.

Tal como no modelo BICHOS, a competição dentro de cada espécie estabiliza a dinâmica, impedindo oscilações de grande amplitude nas populações. Neste regime, as flutuações estocásticas sobrepõem-se a um padrão regular de oscilações característico dos modelos de Lotka-Volterra, com um período bem definido e um desfasamento de um quarto de ciclo entre as duas populações.

QUESTÕES
--------
1. Considere o modelo sem competição (selector COMPETICAO? em "off").
   a) Corra a simulação para a seguinte escolha de parâmetros: Número inicial de sardinhas, 200; número inicial de tubarões, 100; taxa de reprodução das sardinhas, 3%; taxa de mortalidade dos tubarões, 5%; taxa de predação de sardinhas, 90%; e taxa de reprodução dos tubarões, 70%. A que se deve o desfasamento entre as oscilações do número de sardinhas e as oscilações no número de tubarões?
   b) Corra agora a simulação com taxa de predação de sardinhas a 40%, e os mesmos valores do caso anterior para os outros parâmetros. Como explica que a extinção das sardinhas seja mais provável neste segundo caso?
   c) Procure estabilizar a simulação variando aqueles 6 parâmetros, e observe o efeito de cada um deles.

2. Considere agora o modelo com competição (selector COMPETICAO? em "on").
   a) Observe a evolução da população experimentando pôr alternativamente COMPETICAO-SARDINHAS e COMPETICAO-TUBAROES com valores pouco maiores do que zero. Qual dos efeitos é mais eficaz para estabilizar a dinâmica global? Porquê?
   b) Tome os parâmetros indicados em 1.a), juntamente com 5% para a taxa de competição entre sardinhas e 0% para a taxa de competição entre tubarões. Deixe evoluír o sistema e faça uma estimativa do período das oscilações. Aumente para o dobro, separadamente, a taxa de reprodução das sardinhas, a taxa de mortalidade dos tubarões, e as duas em conjunto. Observe o efeito destas modificações no período das oscilações.
   c) Analise agora o efeito das mesmas variações de parâmetros no valor médio das populações de cada uma das espécies.
   d) A partir dos valores finais usados em 2.b) e 2.c), varie agora o valor dos parâmetros PREDACAO-SARDINHAS e REPRODUCAO-TUBAROES, tomando por exemplo 50% e 40%, respectivamente. O período das oscilações varia significativamente? E o valor médio das populações de cada espécie?

VARIANTES E EXTENSÕES
---------------------
Procure introduzir efeitos de mortalidade por causas naturais na população das sardinhas, para além dos causados pela predação.

Nos gráficos realizados tem-se as POPULACOES em função da GERACAO. Procure fazer um outro gráfico da forma tubarões vs sardinhas.
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

sardinha
false
0
Polygon -7566196 true true 295 21 294 279 182 152
Circle -7566196 true true 0 46 212

tubarao
false
0
Polygon -7566196 true true 3 123 29 96 82 86 257 116 294 74 292 195 249 160 72 181 6 173 73 142
Polygon -7566196 true true 148 98 187 54 207 106

@#$#@#$#@
NetLogo 2.0.0
@#$#@#$#@
setup
set grass? true
repeat 75 [ go ]
@#$#@#$#@
@#$#@#$#@