globals [        ;Declaração das variáveis globais.
         tempo   ;Permite saber o tempo de cálculo.
         porta   ;O valor lógico desta variável determina se o programa é ou não abortado.
         NP      ;Número de células pintadas para cada partição.   
         NPOLD
         NPOLD2
         lado
         ladoOLD
         ladoOLD2
         verde   ;
         azul    ;;Nomear duas cores que tal como o "black" não podem fazer parte dos objectos a calcular a dimensão.
        ]        ;;;O verde será a cor dos diversos quadrados que aproximam o objecto. O azul é a cor dos patches restantes.
        
patches-own [ pintado ] ;Variável dos patches. Se os patches representados pertencerem ao objecto que se pretende calcular a dimensão
                        ;;os patches representantes (em cada partição) têm pintado diferente de zero, caso contrário têm pintado igual a
                        ;;;zero tal como todos os patches não representantes.

to apagar 
   clear-all
end

to desenhar      ;para remover esta função e o botão
if mouse-down?
  [ 
   set pcolor-of patch-at mouse-xcor mouse-ycor green
   ask patches-from patches with[pcolor = green] [patches in-radius-nowrap raio] [set pcolor red]  
  ]
end

to calculadimensao   ;Esta função é executada quando se pressiona Calcula Dimensão.
  locals [ 
          n       ;Variável auxiliar que indica o número de pontos que se pretende desenhar no gráfico.  
          rx ry   ;Variáveis auxiliares que tomam os valores das coordenadas dos patches representantes.
         ]
  reset-timer     ;Inicializa o contador interno da linguagen a zero e começa a contar o tempo.
  
  set NPOLD 0
  set ladoOLD 0
  
  set verde (green + 0.1);
  set azul (blue + 0.1)  ;;definição das novas cores
  set porta true  ;Fica com este valor lógico até indicação contrária do utilizador, aí o programa aborta.
  inicializa-grafico 
 set lado 256
 while [ lado >= 1 ]
    [
     ask patches [ set pintado 0 ] ;A cada nova partição é necessário "limpar" todos os representantes,
                                   ;;pois eles são diferentes de particão para partição.
     ask patches [ representantes ];Cada patch calcula o seu representante. Se o patch pertence ao objecto para o qual se pretende saber
                                   ;;a dimensãoentão incrementa a variável pintado do seu representante de uma unidade. 
     if ver-particao ;Permite ao utilizador ver as sucessivas partições da janela e a aproximação (por quadrados) do objecto. 
       [
         ask patches [
                      set rx lado * int ((pxcor + screen-edge-x) / lado) - screen-edge-x ;
                      set ry lado * int ((pycor + screen-edge-y) / lado) - screen-edge-y ;;Como cada patch calcula o seu representante.
                      ifelse (pintado-of patch rx ry != 0)  ;Se o representante está "pintado" então os representados fazem parte da 
                        [                                   ;;aproximação e devem colorir-se de verde.
                         if pcolor = black or pcolor = azul
                           [ set pcolor verde ]
                        ]
                        [ set pcolor azul ];Caso o representante não esteja pintado então o patch sabe que não faz parte da aproximação,
                     ]                     ;;fica azul.
       ]
     set NPOLD2 NPOLD
     set ladoOLD2 ladoOLD
     set NPOLD NP
     set ladoOLD lado
     set NP 0 ;O número de células com pintado != 0 é inicializado a zero em cada novo valor do lado  
     ask patches [ ;Contar o número de patches com pintado != 0, isto é, o número de representantes "pintados".
                  if pintado > 0 
                    [ set NP NP + 1 ]
                 ]
     desenha-ponto            ;Desenha um novo ponto no gráfico.
     ;set lado (lado - passo) ;Actualizar o lado.
     set lado lado / 2 
     if not porta   ;Caso o utilizador tenha pressionado Parar, o programa acaba aqui.
       [ set tempo timer stop ]
    ]
  ;set lado (lado + passo)
  set lado lado * 2
  set ladoOLD ladoOLD * 2
  set ladoOLD2 ladoOLD2 * 2
  tangente  ;Traça a recta que passa no ponto (0.0) e no ponto do gráfico que corresponde ao menor valor de lado usado. 
            ;;Calcula a dimensão fractal com base do declive na recta anterior.
  set tempo timer ;Dá o tempo de cálculo.
end

to inicializa-grafico ;Desenha duas rectas de enquadramento
  set-current-plot "Dimensao"
  set-current-plot-pen "dimensao 1"
  auto-plot-off
  plotxy 0 0
  plotxy 10 10
  set-current-plot-pen "dimensao 2"
  plotxy 0 0
  plotxy 10 20
  auto-plot-on
end

to representantes
  locals [ rx ry ]
  set rx lado * int ((pxcor + screen-edge-x) / lado) - screen-edge-x;
  set ry lado * int ((pycor + screen-edge-y) / lado) - screen-edge-y;;Como cada patch calcula as coordenadas do seu representante.
  if pcolor != black and pcolor != azul and pcolor != verde       ;Se o patch respectivo pertence ao objecto então incrementa a variável  
    [ set (pintado-of patch rx ry) (pintado-of patch rx ry) + 1 ] ;;pintado do seu represntante de uma unidade.
end

to desenha-ponto  ;Desenha um ponto no gráfico com os valores que variáveis globais (NP e lado) tenham no momento em que é chamada. 
  set-current-plot "Dimensao"
  set-current-plot-pen "pontos"
  if NP = 0  
    [
     user-message "Não desenhou nada!"
     stop
    ] 
  if NP != 1  ;Toma-se como unidade de comprimento a largura da janela. 
    [
     plotxy (ln (screen-size-x / lado)) (ln NP) 
    ]
end


             ;Traça a recta que passa no ponto (0.0) e no ponto do gráfico que corresponde ao menor valor de lado usado. 
to tangente  ;;Calcula a dimensão fractal com base do declive na recta anterior.
  locals [ dec const ]
  set-current-plot "Dimensao"
  set-current-plot-pen "tangente"
  auto-plot-off
  
  set dec ( ln NPOLD - ln NPOLD2 ) / ( ln (screen-size-x / ladoOLD) - ln (screen-size-x / ladoOLD2) )
  set const ( ln NPOLD - dec * ln (screen-size-x / ladoOLD) )
 
  ppu
  plotxy 0 const
  ppd
  plotxy (10 * ln (screen-size-x / ladoOLD)) (10 * (ln (screen-size-x / ladoOLD)) * dec + const)
  auto-plot-on
  show "Dimensão fractal: " + (dec)
end

to parar 
  set porta false
end

to importarmundo
 locals [nomeficheiro ax ay sx sy tx ty]

 file-open user-choose-file
 set sx file-read
 set sy file-read
 
 show "sx: "+ sx +"   sy: "+ sy
 set ay (- screen-edge-y)
 repeat sy
 [
   set ax (- screen-edge-x)
   repeat sx
   [
     if file-at-end? [
       user-message "erro na leitura, ficheiro pequeno demais"
     ]
     ask patch ax ay [
       set pcolor file-read
     ]
     set ax ax + 1
   ]
   set ay ay + 1
 ]
 
 file-close
end

; Versão ICES Copyright 2004, Centro de Física Teórica e Computacional
@#$#@#$#@
GRAPHICS-WINDOW
432
10
955
554
256
256
1.0
1
10
1
1
1

CC-WINDOW
14
476
383
589
Command Center

BUTTON
194
98
343
131
Apagar
apagar
NIL
1
T
OBSERVER
T

BUTTON
432
559
530
592
Desenhar 
desenhar
T
1
T
OBSERVER
T

MONITOR
13
419
188
468
Células Ocupadas
NP
3
1

PLOT
13
139
383
411
Dimensao
Ln(1/L)
Ln(N)
0.0
7.0
0.0
11.0
true
true
PENS
"dimensao 1" 1.0 0 -16776961 true
"dimensao 2" 1.0 0 -65281 true
"pontos" 1.0 2 -16777216 true
"tangente" 1.0 0 -8716033 true

SLIDER
538
559
710
592
raio
raio
0
20
16
1
1
NIL

BUTTON
194
57
343
90
Parar Cálculo
parar
NIL
1
T
OBSERVER
T

MONITOR
211
419
383
468
Tempo de Cálculo (min)
tempo / 60
3
1

BUTTON
194
14
343
47
Calcula Dimensão
calculadimensao
NIL
1
T
OBSERVER
T

SWITCH
36
14
184
47
ver-particao
ver-particao
1
1
-1000

BUTTON
37
97
185
130
Importar Mundo
importarmundo
NIL
1
T
OBSERVER
T

@#$#@#$#@
INTRODUÇÃO
----------

Nem comprimento nem área servem para medir o tamanho dos objectos fractais.
Por exemplo, todos os fractais geométricos que construímos com o primeiro programa deste módulo têm comprimento infinito e área zero. São "mais" do que linhas, e "menos" do que superfícies. O conceito de dimensão fractal dá uma resposta ao problema de medir o tamanho destes objectos.

Para os objectos geométricos ‘clássicos’ existe uma relação simples entre a dimensão, o número de blocos necessário para os recobrir, e o tamanho dos blocos. No caso de segmentos de recta, quadrados, ou cubos, conforme estejamos em dimensão um, dois ou três, essa relação é 
Nn = (1/ Ln)^d,
onde Nn é o número de quadrados de lado Ln do recobrimento e d a dimensão. È fácil comprovar este resultado. Por exemplo, um quadrado de lado 1 é recoberto por 4 quadrados de lado 1/2, 16 quadrados de lado 1/4, ... 

A equação anterior pode ser rescrita na forma
d =  log Nn  /log (1/Ln)
que põe em evidência a simplicidade desta lei. É uma lei de potência, portanto a dependência do logaritmo do número de blocos no logaritmo do inverso do tamanho destes é linear. Num gráfico log-log, esta relação traduz-se por uma recta, e o declive dessa recta é a dimensão, d. 

Para objectos de formas mais complicadas, a equação anterior pode não se verificar.
No entanto, a relação de proporcionalidade
d ~ log Nn  /log (1/Ln)				(1)
é recuperada assimptoticamente à medida que o recobrimento se toma mais fino.

Isto motiva tomar a relação (1), no limite Ln->0, como uma definição alternativa de dimensão, chamada dimensão de contagem de blocos, por razões óbvias. A dimensão definida desta maneira coincidirá com a dimensão habitual para os objectos da geometria tradicional, e é em geral não inteira para os objectos fractais. É uma das definições posíveis de dimensão fractal, e é nela que se baseia o cálculo que este programa executa.

O cálculo da dimensão de contagem de blocos para a ilha de Koch dá 
d = log 4/ log 3 ~ 1.26 . A curva de Koch tem dimensão fractal não inteira, maior que a de uma linha, e menor que a de uma superfície. O mesmo cálculo para a árvore de Sierpinski dá d = log 3/ log 2 ~ 1.58, e para o quadrado de Sierpinsky d = log 8/ log 3 ~ 1.89. Não é difícil verificar que, em geral, para fractais construídos recursivamente como nestes exemplos a partir de c cópias de si próprios rescaladas por um factor 1/f, se terá d = log c/ log f.

Note que a dimensão de contagem de blocos é um limite, e que um fractal 'autêntico' tem estrutura não trivial em todas as escalas, enquanto que nos objectos com que trabalhamos aqui o detalhe está limitado pela resolução da figura. Pela mesma razão, não faz sentido construir recobrimentos mais finos do que o tamanho de um pixel. 



UTILIZAÇÃO
----------

Este programa usa o algoritmo da dimensão de contagem de blocos para obter valores aproximados para a dimensão fractal das figuras representadas na janela gráfica.
Essas figuras podem ser desenhadas 'à mão' neste programa, premindo o botão "DESENHAR" e 'clickando' ou arrastando o rato na janela gráfica para aí criar uma imagem.
Também podem ser importadas de outros programas, premindo o botão "IMPORTAR MUNDO"
para carregar na janela gráfica ficheiros previamente criados.  

Como viu, a ideia para o cálculo da dimensão de contagem de blocos de uma imagem é muito simples. Basta dividir a janela gráfica em quadrados cada vez mais pequenos e ir contando quantos desses quadrados possuem pelo menos um patch que faça parte da imagem. O programa executa essa operação com o botão "CALCULA DIMENSÃO", e vai representando num gráfico log Nn em função de log (1/Ln). À medida que a partição se torna mais fina, esses pontos aproximam-se de uma recta cujo declive é um valor aproximado da dimensão fractal. Esse valor é apresentado na janela de comandos no fim do cálculo.

A opção "VER-PARTIÇÃO" permite ao utilizador ver como é que a imagem está a ser coberta pelos quadrados da partição. Os quadrados que ficam a verde fazem parte da aproximação ao objecto, os outros quadrados da partição ficam azuis. O monitor "Células Ocupadas" dá a indicação do número de quadrados verdes em cada partição. 



OBSERVAÇÕES E QUESTÕES
----------------------

1. Use o botão "DESENHAR" para criar imagens na janela gráfica e calcule a dimensão de contagem de blocos destas imagens. Procure desenhar áreas e linhas regulares, e conjuntos de pontos, e analise os resultados. Em particular, procure explicar o comportamento dos pontos que se obtêm à medida que a partição se torna mais fina.

2. Calcule a dimensão de contagem de blocos dos fractais gerados pelo programa Fractais Geométricos, e compare com os valores exactos.

3. Calcule a dimensão de alguns dos fractais gerados pelo programa Atractores Estranhos, incluindo o atractor de Hénon (d ~ 1.26).
 
4. Calcule a dimensão da fronteira da região percorrida por uma tartaruga no programa Marcha Aleatória (d ~ 4/3).

5. Repare que em todos os cálculos que efectuou, o programa ajusta a recta aos penúltimo e antepenúltimo pontos, em vez de aos dois últimos. Esta escolha altera de maneira sistemática a estimativa da dimensão ? Parece-lhe razoável desprezar o ponto que corresponde à partição mais fina ?

6. No módulo 1, no programa Infiltração de Óleos em Solos Porosos, para a porosidade correspondente à transição de percolação o solo contaminado forma um agregado fractal. Calcule a sua dimensão fractal (não se esqueça de alterar as cores convenientemente, assim como o tamanho e propriedades da janela gráfica, e use as funções "export world" e "import world" que o programa disponibiliza em 'file' ).  



VARIANTES E EXTENSÕES
---------------------

Adapte o progrma de maneira permitir fazer o refinamento da partição de maneira aritmética, em vez de geométrica. Use esta variante para explorar com mais pontos a região das partições finas que serviu de base à estimativa da dimensão fractal nos exemplos que calculou antes.  

Adapte o programa por forma a permitir outro tipo de recobrimentos, por exemplo por discos em vez de quadrados, e compare os resultados obtidos.


@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@