globals [            ;variáveis globais
         x y 
         xmin xmax ymin ymax   ;servem para localizar o objecto atractor no plano R2
         porta?                ;variável que caso seja "false" por indicação do utilizador, permite abortar o desenho 
         xfact yfact fact      ;factores de reescalamento 
        ]

to desenhar         ;procedimento executado após se pressionar o botão Desenhar
  locals [ xo yo ]
  set x pontoinix   ;é o utilizador que escolhe o ponto inicial
  set y pontoiniy
  repeat 5000       ;calculam-se 5000 iterações da aplicação para que se obtenha um ponto que estará mais perto do atractor  
    [               ;assim elimina-se a influência das condições iniciais
      set xo x
      set yo y      ;fórmula da aplicação quadrática mais geral possível a 2D 
      set x (a1 + a2 * xo + a3 * xo * xo + a4 * xo * yo + a5 * yo + a6 * yo * yo) 
      set y (a7 + a8 * xo + a9 * xo * xo + a10 * xo * yo + a11 * yo + a12 * yo * yo)
      if abs x > 10 ^ 100 or abs y > 10 ^ 100  ;para certos valores dos parâmetros a distância do ponto (x,y) à origem pode divergir 
        [                                      ;e isso causa erros de cálculo no computador
         user-message " Pontos divergem"
         stop
        ]
    ]     
  set xmin x     ;após eliminada a influência das condições iniciais
  set xmax x
  set ymin y
  set ymax y
  repeat 5000    ;fazem-se novamente algumas iterações de modo a saber em que região do plano está o objecto e que tamanho tem
    [
      set xo x
      set yo y               
      if x < xmin [ set xmin x ]
      if x > xmax [ set xmax x ]
      if y < ymin [ set ymin y ]
      if y > ymax [ set ymax y ]
      set x (a1 + a2 * xo + a3 * xo * xo + a4 * xo * yo + a5 * yo + a6 * yo * yo) 
      set y (a7 + a8 * xo + a9 * xo * xo + a10 * xo * yo + a11 * yo + a12 * yo * yo)
      if abs x > 10 ^ 100 or abs y > 10 ^ 100
        [
         user-message " Pontos divergem"
         stop
        ]
    ]
  set fact 0.8 ;a figura a desenhar ocupará só 80% da janela disponível
  desenha x xmin xmax y ymin ymax
end

to desenha [ xd xmind xmaxd yd ymind ymaxd ] ;função que desenha no campo gráfico o atractor pretendido
  locals [ xo yo vx vy ]                     ;esta função necessita de saber o enquadramento do objecto para que o possa reescalar  
  set xo xmaxd - xmind                       ;e transladar para a nossa janela
  set yo ymaxd - ymind
  if xo = 0 [ set xo 0.0001 ] ;se o objecto for um ponto fixo então xo e yo seriam 0, assim fazem-se 0.0001 (valor pequeno) 
  if yo = 0 [ set yo 0.0001 ] ;para que não dê erro ao se dividir na instrução seguinte por xo e yo
  set xfact screen-size-x * fact / xo ;
  set yfact screen-size-y * fact / yo ;calcula-se o factor de reescalamento da figura de modo a esta preencher fact * 100% da janela
  
  set porta? true ;caso porta? seja false (por indicação do utilizador que pressionou parar) no fim desta função pára-se de desenhar
  set x xd        ;caso porta? seja true são desenhados npontos pontos
  set y yd
                 
  repeat npontos
    [
     set vx int((x - xmind) * xfact - screen-edge-x * fact) ;aqui faz-se o reescalamento do objecto e a sua translacção
     set vy int((y - ymind) * yfact - screen-edge-y * fact) ;note que é necessário fazer um casting para inteiro pois as coordenados
                                                            ;dos patches são sempre inteiras 
     if abs vx < screen-edge-x and abs vy < screen-edge-y ;se o ponto estiver dentro da janela gráfica então é desenhado 
       [                 ;por construção quando se executa a fc desenha chamada pela fc desenhar o ponto está sempre dentro da janela
        ask patch vx vy  ;contudo quando se executa a fc desenha chamada pela fc zoom por vezes o ponto cai fora da janela 
          [              ;disponível, é isso que justifica este teste     
           ifelse Gradiente-Cor
             [                       ;o utilizador pode escolher fazer o desenho só a vermelho ou com diferentes tons de vermelho
              ifelse pcolor = black  
                [ set pcolor 12 ]
                [ set pcolor (pcolor + 0.1) ];no caso de escolher utilizar vários tons de vermelho deve notar que pontos de vermelho mais
              if pcolor > red                ;vivo indicam que esse ponto foi vizitado pela dinâmica mais vezes que pontos
                [ set pcolor red ]           ;que estejam pintados a vermelho mais escuro
             ]
             [ set pcolor red ]            
          ]
       ]
     set xo x
     set yo y               
     set x (a1 + a2 * xo + a3 * xo * xo + a4 * xo * yo + a5 * yo + a6 * yo * yo) 
     set y (a7 + a8 * xo + a9 * xo * xo + a10 * xo * yo + a11 * yo + a12 * yo * yo)
     if abs x > 10 ^ 100 or abs y > 10 ^ 100
       [
        user-message " Pontos divergem"
        stop
       ]
     if not porta? [ stop ] ;é aqui que a fc desenha aborta após indicação do utilizador
   ]
  set pontoinix x           ;o último ponto desenhado é guardado 
  set pontoiniy y
end

to zoom   ;esta função faz uma ampliação da zona seleccionada pelo utilizador
  locals [ xcormin xcormax ycormin ycormax ]
  escolherpontos ;função que permite escolher os pontos cujas coordenadas delimitam a zona a ampliar, esses pontos ficam pintados a verde 
  set xcormin min values-from (patches with [ pcolor = green ]) [ pxcor ];aqui obtêm-se as coordenadas dos patches seleccionados
  set xcormax max values-from (patches with [ pcolor = green ]) [ pxcor ]
  set ycormin min values-from (patches with [ pcolor = green ]) [ pycor ]
  set ycormax max values-from (patches with [ pcolor = green ]) [ pycor ] 
  set xmax (((screen-edge-x * fact + xcormax) / xfact) + xmin) ;nestas instruções executa-se as transformações inversas à translacção
  set xmin (((screen-edge-x * fact + xcormin) / xfact) + xmin) ;e ao reescalamento. Sabe-se a coordenada dos patches mas precisa-se 
  set ymax (((screen-edge-y * fact + ycormax) / yfact) + ymin) ;de saber a que ponto de R2 isso corresponde.
  set ymin (((screen-edge-y * fact + ycormin) / yfact) + ymin) ;os "reporter" que se encontram ao lado do campo gráfico podem 
                                                               ;dar ao utilizador uma ideia das coordenadas de R2 dos pontos escolhidos 
  ask patches with [ pxcor > xcormin and xcormax > pxcor and pycor > ycormin and ycormax > pycor and pcolor = black ]
    [ set pcolor green ]  ;os patches pertencentes à zona seleccionada aparecem pintados a verde durante 3 segundos
  wait 3
  ask patches
    [ set pcolor black ] ;para que se possa fazer o desenho da zona ampliada é necessário apagar o desenho anterior  
  set fact 1.0           ;o desenho gerado pelo zoom ocupa toda a janela gráfica
  desenha x xmin xmax y ymin ymax ;faz o desenho da zona seleccionada
end

to escolherpontos ;função que permite escolher os pontos cujas coordenadas delimitam a zona a ampliar,   
  locals [ i ]    ;esses pontos mudam a cor para verde
  set i 0
  while[ i != 1 ]
   [
    if mouse-down? ;o utilizador deve seleccionar os pontos com o rato (clicando)
      [ 
       set pcolor-of patch-at mouse-xcor mouse-ycor green 
      ]  
    if (count patches with [ pcolor = green ]) >= 2 ;são necessários dois pontos (extremos da caixa)
      [
       set i (i + 1)     
      ]
   ]
end

to parar ;permite parar o procedimento desenhar 
  set porta? false
end

to zeros ;inicializa todos os parâmetros do modelo a zero
  set a1 0.0 set a2 0.0 set a3 0.0 set a4 0.0 set a5 0.0 set a6 0.0 set a7 0.0 set a8 0.0 set a9 0.0 set a10 0.0 set a11 0.0 set a12 0.0 
  set pontoinix 0
  set pontoiniy 0
end

to apagar ;apaga a janela gráfica e a condição inicial
  ca
  set pontoinix 0
  set pontoiniy 0
end

to inicializaparametros ;inicializa os parâmetros do modelo de acordo com a imagem da biblioteca seleccionada
  locals [ 
          listanomes      ;onde estão os nomes das imagens da biblioteca  
          listaparametros ;lista de listas (matriz). Cada linha da matriz é uma lista, que possui os parâmetros de uma imagem
                          ;as linhas da matriz estão ordenadas de acordo com a ordem da listanomes
          lista           ;após se saber qual a imagem seleccionada (ou qual a linha (lista) da matriz seleccionada) esta variável guarda-a
         ]
  set listanomes (list "AMTMNQQXUYGA" "CVQKGHQTPHTE" "FIRCDERRPVLD" "GIIETPIQRRUL" "GLXOESFTTPSV" "GXQSNSKEECTX" "HGUHDPHNSGOH"
                       "ILIBVPKJWGRR" "LUFBBFISGJYS" "MCRBIPOPHTBN" "MDVAIDOYHYEA" "ODGQCNXODNYA" "QFFVSLMJJGCR" "UWACXDQIGKHF"
                       "VBWNBDELYHUL" "WNCSLFLGIHGL" "MCRBIPOPHTBL" "WCRBIPOPDTBL")
  set listaparametros (list (list -1.2 0.0 0.7 0.0 0.1 0.4 0.4 1.1 0.8 1.2 -0.6 -1.2)
                            (list -1.0 0.9 0.4 -0.2 -0.6 -0.5 0.4 0.7 0.3 -0.5 0.7 -0.8)
                            (list -0.7 -0.4 0.5 -1.0 -0.9 -0.8 0.5 0.5 0.3 0.9 -0.1 -0.9)
                            (list -0.6 -0.4 -0.4 -0.8 0.7 0.3 -0.4 0.4 0.5 0.5 0.8 -0.1)
                            (list -0.6 -0.1 1.1 0.2 -0.8 0.6 -0.7 0.7 0.7 0.3 0.6 0.9)
                            (list -0.6 1.1 0.4 0.6 0.1 0.6 -0.2 -0.8 -0.8 -1.0 0.7 1.1)
                            (list -0.5 -0.6 0.8 -0.5 -0.9 0.3 -0.5 0.1 0.6 -0.6 0.2 -0.5)
                            (list -0.4 -0.1 -0.4 -1.1 0.9 0.3 -0.2 -0.3 1.0 -0.6 0.5 0.5)
                            (list -0.1 0.8 -0.7 -1.1 -1.1 -0.7 -0.4 0.6 -0.6 -0.3 1.2 0.6)
                            (list 0.0 -1.0 0.5 -1.1 -0.4 0.3 0.2 0.3 -0.5 0.7 -1.1 0.1) 
                            (list 0.0 -0.9 0.9 -1.2 -0.4 -0.9 0.2 1.2 -0.5 1.2 -0.8 -1.2) 
                            (list 0.2 -0.9 -0.6 0.4 -1.0 0.1 1.1 0.2 -0.9 0.1 1.2 -1.2) 
                            (list 0.4 -0.7 -0.7 0.9 0.6 -0.1 0.0 -0.3 -0.3 -0.6 -1.0 0.5) 
                            (list 0.8 1.0 -1.2 -1.0 1.1 -0.9 0.4 -0.4 -0.6 -0.2 -0.5 -0.7) 
                            (list 0.9 -1.1 1.0 0.1 -1.1 -0.9 -0.8 -0.1 1.2 -0.5 0.8 -0.1) 
                            (list 1.0 0.1 -1.0 0.6 -0.1 -0.7 -0.1 -0.6 -0.4 -0.5 -0.6 -0.1) 
                            (list 0.0 -1.0 0.5 -1.1 -0.4 0.3 0.2 0.3 -0.5 0.7 -1.1 -0.1)
                            (list 0.0 -1.0 0.5 -1.1 -0.4 0.3 0.2 0.3 -0.5 0.7 -1.1 -1.1)
                        )
  set lista (item (position imagem listanomes) listaparametros) 
  (set a1 item 0 lista) (set a2 item 1 lista) (set a3 item 2 lista) (set a4 item 3 lista) (set a5 item 4 lista) (set a6 item 5 lista) 
  (set a7 item 6 lista) (set a8 item 7 lista) (set a9 item 8 lista) (set a10 item 9 lista) (set a11 item 10 lista) (set a12 item 11 lista) 
end


;Esta função foi desenhada para ser usada no "Command Center"
;O utilizador deve chamar a função digitando o seu nome e passando-lhe como argumento
;uma "string" composta por 12 letras (nome de uma imagem). Por exemplo NomeImagem "NETLOGO?CFTC"
;A função inicializa automaticamente os parâmetros 
to NomeImagem[lista] 
locals[i listaletras listavalores LM]
set i 0
set listaletras (list "?" "#" "A" "B" "C" "D" "E" "F" "G" "H" "I" "J" "K" "L" "M" "N" "O" "P" "Q" "R" "S" "T" "U" "V" "W" "X" "Y" "Z" "[")
set listavalores (list -1.4 -1.3 -1.2 -1.1 -1.0 -0.9 -0.8 -0.7 -0.6 -0.5 -0.4 -0.3 -0.2 -0.1 0.0 0.1 0.2 0.3 0.4 0.5 0.6 0.7 0.8 0.9 1.0 1.1 1.2 1.3 1.4)
set LM (list 1 2 3 4 5 6 7 8 9 10 11 12) ;serve para inicializar a lista de comprimento 12, os valores usados são de todo irrelevantes
repeat length lista
  [
   set LM replace-item i LM (item (position (item i lista) listaletras) listavalores) ;constrói a lista de parâmetros numéricos
   set i i + 1
  ]
(set a1 item 0 LM) (set a2 item 1 LM) (set a3 item 2 LM) (set a4 item 3 LM) (set a5 item 4 LM) (set a6 item 5 LM) 
  (set a7 item 6 LM) (set a8 item 7 LM) (set a9 item 8 LM) (set a10 item 9 LM) (set a11 item 10 LM) (set a12 item 11 LM)
end

;exporta o mundo (escreve o valor de todas as variáveis)
;para um ficheiro de nome nomeficheiro 
to exportarmundo
 locals [nomeficheiro ax ay]
 set nomeficheiro user-choose-new-file

 if file-exists? nomeficheiro [
   file-delete nomeficheiro
 ]
 
 file-open nomeficheiro
 file-print screen-size-x
 file-print screen-size-y
 
 show "sx: "+ screen-size-x + "  sy: "+ screen-size-y
 set ay (- screen-edge-y)
 repeat screen-size-y
 [
   set ax (- screen-edge-x)
   repeat screen-size-x
   [
     ask patch ax ay [
       file-print pcolor
     ]
     set ax ax + 1
   ]
   set ay ay + 1
 ]
 file-close
end

; Versão ICES Copyright 2004, Centro de Física Teórica e Computacional
@#$#@#$#@
GRAPHICS-WINDOW
457
10
980
554
256
256
1.0
1
10
1
1
1

CC-WINDOW
9
507
434
608
Command Center

SLIDER
7
10
223
43
a1
a1
-1.2
1.2
-1.2
0.1
1
NIL

SLIDER
7
47
223
80
a2
a2
-1.2
1.2
-0.6
0.1
1
NIL

SLIDER
7
85
223
118
a3
a3
-1.2
1.2
-0.5
0.1
1
NIL

SLIDER
8
122
224
155
a4
a4
-1.2
1.2
0.1
0.1
1
NIL

SLIDER
9
159
225
192
a5
a5
-1.2
1.2
-0.7
0.1
1
NIL

SLIDER
9
196
225
229
a6
a6
-1.2
1.2
0.2
0.1
1
NIL

SLIDER
9
232
225
265
a7
a7
-1.2
1.2
-0.9
0.1
1
NIL

SLIDER
9
269
225
302
a8
a8
-1.2
1.2
0.9
0.1
1
NIL

SLIDER
9
305
225
338
a9
a9
-1.2
1.2
0.1
0.1
1
NIL

SLIDER
9
341
225
374
a10
a10
-1.2
1.2
-0.3
0.1
1
NIL

SLIDER
9
378
225
411
a11
a11
-1.2
1.2
-1.0
0.1
1
NIL

SLIDER
9
415
225
448
a12
a12
-1.2
1.2
0.3
0.1
1
NIL

SLIDER
9
460
225
493
npontos
npontos
0
5000000
1942675
1
1
NIL

BUTTON
244
332
339
365
Desenhar
desenhar
NIL
1
T
OBSERVER
T

BUTTON
244
409
339
442
Apagar
apagar
NIL
1
T
OBSERVER
T

MONITOR
549
558
606
607
xmin
xmin
3
1

MONITOR
398
70
455
119
ymax
ymax
3
1

MONITOR
907
561
964
610
NIL
xmax
3
1

MONITOR
398
439
455
488
ymin
ymin
3
1

CHOICE
234
10
401
55
imagem
imagem
"AMTMNQQXUYGA" "CVQKGHQTPHTE" "FIRCDERRPVLD" "GIIETPIQRRUL" "GLXOESFTTPSV" "GXQSNSKEECTX" "HGUHDPHNSGOH" "ILIBVPKJWGRR" "LUFBBFISGJYS" "MCRBIPOPHTBN" "MCRBIPOPHTBL" "MDVAIDOYHYEA" "ODGQCNXODNYA" "QFFVSLMJJGCR" "UWACXDQIGKHF" "VBWNBDELYHUL" "WNCSLFLGIHGL"
16

BUTTON
234
104
328
137
Zeros
zeros
NIL
1
T
OBSERVER
T

BUTTON
244
370
339
403
Parar
parar
NIL
1
T
OBSERVER
T

BUTTON
234
67
328
100
Inicializar
inicializaparametros
NIL
1
T
OBSERVER
T

BUTTON
244
460
339
493
Zoom
zoom
NIL
1
T
OBSERVER
T

SLIDER
233
154
405
187
pontoinix
pontoinix
-10.0
10.0
0.0
0.01
1
NIL

SLIDER
233
194
405
227
pontoiniy
pontoiniy
-10
10
0.0
0.01
1
NIL

SWITCH
234
238
388
271
Gradiente-Cor
Gradiente-Cor
0
1
-1000

BUTTON
457
558
546
591
Exportar
exportarmundo
NIL
1
T
OBSERVER
T

@#$#@#$#@
INTRODUÇÃO
----------

A evolução no tempo de sistemas físicos, químicos, biológicos e sociais pode ser modelada matematicamente através de equações diferenciais ou de regras de iteração.
Por exemplo, a equação diferencial X' = a X, cuja solução é X(T)= X(0) exp (a T), modela a desintegração radioactiva, se o parâmetro a for negativo, e o crescimento exponencial de uma população se a for positivo. Ambos estes exemplos, como todos os modelos formulados com equações diferenciais, consideram o tempo uma variável contínua. Em muitos casos, um modelo é naturalmente formulado considerando apenas instantes discretos do tempo, separados por intervalos constantes. Nestes casos, os modelos matemáticos são regras de iteração, em vez de equações diferenciais. Um bom exemplo é outra vez a dinâmica de populações, em que faz sentido querer saber apenas os sucessivos valores da população nos instantes T1, T2, ..., Tn, separados pelo intervalo de tempo típico de uma geração. O modelo discreto correspondente ao modelo de crescimento exponencial é a regra de iteração Xn+1 = b Xn, com n inteiro e a constante b=exp (a Tg), onde Tg é o tempo médio de uma geração. Também podemos pensar nos modelos a tempo discreto como 'imagens estroboscópicas' de modelos a tempo contínuo. Estes modelos são os mais fáceis de explorar computacionalmente, porque os computadores também trabalham com variáveis discretas.

Ao contrário dos modelos lineares como os que usámos como exemplo, os modelos não lineares podem ter soluções muito complicadas, e exibir o tipo de comportamento que se designa genericamente por caos. Um exemplo muito conhecido são as equações de Lorenz, que para certos valores dos parâmetros têm um atractor caótico, isto é, uma região do espaço que atrai todas, ou quase todas, as condições iniciais e sobre a qual órbitas próximas divergem exponencialmente. Neste caso, como em muitos outros, o atractor caótico é, do ponto de vista geométrico, um fractal, e chama-se um atractor estranho.  
    
Neste programa vamos explorar um sistema não linear discreto a duas variáveis, ou seja, uma regra de iteração da forma Xn+1 = f1(Xn,Yn), Yn+1 = f2(Xn,Yn), com a não linearidade mais simples, em que f1 e f2 são funções quadráticas. Variando os parâmetros do sistema, e deixando as soluções evoluir, veremos como a sua representação no plano das variáveis X,Y vai produzir objectos de inesperada complexidade, que, tal como os fractais geométricos, exibem estrutura não trivial em escalas sucessivamente mais pequenas, mas que, ao contrário destes, não são exactamente auto-semelhantes.  


UTILIZAÇÃO
----------

A regra iterativa usada é a aplicação quadrática do plano mais geral possível 

        Xn+1 = a1 + a2*Xn + a3*Xn*Xn + a4 Xn*Yn + a5*Yn + a6*Yn*Yn
	Yn+1 = a7 + a8*Xn + a9*Xn*Xn + a10 Xn*Yn + a11*Yn + a12*Yn*Yn  
	Aplicação quadrática bi-dimensional

Os 12 parâmetros do modelo (a1 - a12)  podem ser alterados usando o botão correspondente, assim como a condição inicial onde se deseja começar a iteração e o número de pontos (ou de iterações) que se pretende realizar. O programa vai calculando e representando na janela os sucessivos pontos (Xn, Yn) da órbita com essa condição inicial. Para alguns valores dos parâmetros, este sistema não linear tem um atractor estranho.

Convem notar que as primeiras 10.000 iterações não são mostradas no gráfico, pois pretende-se ver o objecto atractor e não o transiente associado a cada condição inicial. Assim, escolhendo parâmetros adequados e qualquer condição inicial que pertença à bacia de atracção do atractor, a figura produzida pelo programa é uma representação aproximada do atractor.

Cada parâmetro pode ter valores desde -1.2 a 1.2 em saltos de 0.1. Apesar deste intervalo corresponder a uma exploração muito grosseira e limitada dos possíveis valores dos parâmetros, corresponde mesmo assim a 25^12 casos diferentes, dos quais cerca de 10^15 têm atractores caóticos.

É preciso notar que nem todos os casos mencionados correspondem a atractores geometricamente diferentes : uns são imagens rodadas dos outros ou imagens ao espelho. 
Pode ainda haver casos que correspondam a ampliações ou reduções, e que serão vistos como idênticos uma vez que, para além de os transladar, o programa reescala os objectos ao tamanho da janela. 

Estas simetrias poderiam ser reduzidas eliminando parâmetros, mas o número de casos distintos a explorar seria ainda muito grande. Por isso, o modelo dispõe de uma biblioteca de imagens (ou parâmetros) para os quais o sistema tem atractores interessantes. Para a usar, basta selecionar um nome no campo "imagem" e pressionar "Inicializar". 

O nome de cada conjunto de parâmetros da biblioteca pode parecer também "estranho", mas cada caracter ASCII do nome corresponde a um determinado valor para o parâmetro respectivo: por exemplo, A representa o valor -1.2, o valor 1.2 representa-se por Y, os valores intermédios (em saltos de 0.1) são representados pelas outras letras do alfabeto. O botão "Zeros" inicializa todos os parâmetros do modelo a zero.

Em vez de utilizar os sliders ou a biblioteca para definir o conjunto de parâmetros da aplicação quadrática, podemos introduzir directamente no "Command Center" a função NomeImagem seguida de um argumento com o "nome" da aplicação. Por exemplo a aplicação de Hénon (ver questão 3), uma das mais conhecidas e estudadas, poderá ser definida escrevendo >NomeImagem "WM?MPMMWMMMM" (neste caso a caracter "?" corresponde ao valor -1.4, que sai fora do intervalo normalmente investigado).

Após a escolha dos parâmetros, a representação da órbita começa se se pressionar "Desenhar". Este processo pode ser interrompido em qualquer instante pressionando "Parar", e pára automaticamente ao ser atingido o número de iterações fixado em "npontos". Para limpar o campo gráfico usa-se "Apagar".

Este modelo possui um botão de "Zoom". Depois de activado, o utilizador tem que escolher, 'clickando' com o rato na janela gráfica, dois pontos de diferentes ordenadas e abcissas. As coordenadas destes pontos delimitam a zona a ser ampliada.  

Este programa possui ainda uma opção de "Gradiente-Cor". Se seleccionada, esta opção vai fazer com que os pontos do desenho que são mais vezes visitados fiquem com uma cor mais brilhante. Isto serve para mostrar que o atractor não é visitado de maneira uniforme, e dá uma ideia das zonas do atractor onde a dinâmica passa mais tempo.


QUESTÕES	
--------

1. Experimente o resultado de alguns dos casos propostos na biblioteca de modelos, e use a opção de zoom para investigar os pormenores de cada fractal. 

2. Experimente as seguintes transformações alterando os parâmetros correspondentes:      
                     (rotação de 90º) X -> Y 
                                      Y -> -X 
                     (rotação de 180º) X -> -X
                                       Y -> -Y
                     (imagem espelho) X -> -X
                                      Y -> Y


3.Uma aplicação muito conhecida e que aparece como caso particular da aplicação quadrática bi-dimensional mais geral é a aplicação de Hénon.
Regra iterativa: Xn+1 = 1 + a*Xn*Xn + b*Yn 
	         Yn+1 = Xn
Experimente os seguintes valores: a=-1.4 b=0.3. Note que nem todos os valores de a e b produzem um objecto atractor, para muitos desses valores a distância dos pontos à origem diverge.  
(Sugestão: utilize a função NomeImagem "WM?MPMMWMMMM")

4.Experimente os seguintes conjuntos de parâmetros (use a função NomeImagem):
WM?MPMMWMMMM, AGHNFODVNJCP, BCQAFMFVPXKQ, DSYUECINGQNV, ELXAPXMPQOBT, EYYMKTUMXUVC, JTTSMBOGLLQF, NNMJRCTVVTYG, OUGFJKDHSAJU, QKOCSIDVTPGY, QLOIARXYGHAJ, TJUBWEDNRORR, TSILUNDQSIFA, UZBJLCDISIIQ, UDUOTLRBKTJD, WLKWPSMOGIGS, CSRKVVQLGFFS, KPNERVOTBYCM.
 
5.Procure os seus próprios atractores, para muitos será a primeira pessoa a vê-los! 

6.Note a grande semelhança entre o nome das imagens MCRBIPOPHTBN e MCRBIPOPHTBL. Apenas diferem no valor do último parâmetro. No entanto, as mudanças de valores dos parâmetros podem ter consequências dramáticas na dinâmica. Escolha um modelo da biblioteca e mande o programa desenhá-lo, vá mudando o valor dos parâmetros à medida que o desenho evolui. Repare na diversidade de atractores que encontra. Tente o seguinte exemplo: coloque o programa a desenhar a imagem "UWACXDQIGKHF" de seguida varie passo a passo o parâmetro a6 até -0.4. Após isto varie o parâmetro a7 até -0.4, interprete o que observa. 

Resposta: Observam-se órbitas periódicas, visíveis a partir dos seus transientes, e curvas invariantes. Para as ver melhor é conveniente reduzir um pouco a velocidade de execução do programa. A órbita da condição inicial (0,0) diverge para a maior parte destes outros valores de a6 e a7. Para iniciar o programa com estes valores, é necessário escolher condições iniciais adequadas. Estas podem ser escolhidas a partir da observação da simulaço proposta. Por exemplo, x=0.7 e y=-0.7 funciona para os valores finais de a6 e a7.

7.Para o seguinte conjunto de parâmetros "KYXEVJLXUYGA" com a condição inicial (0,0), pode observar uma órbita curva invariante, outro tipo de atractor. Varie os parâmetros e veja que atractores como curvas invariantes, órbitas periódicas e pontos fixos são também frequentes.  


VARIANTES E EXTENSÕES
---------------------

Procure fractais para outros intervalos dos parâmetros, editando os diversos "sliders" para mudar os valores.

Adapte o programa de maneira a permitir a exploração numérica das aplicações cúbicas, quárticas ou quínticas.
Por exemplo, Xn+1 = a1 + a2*Xn + a3*Xn*Xn + a4 Xn*Xn*Xn + a5*Xn*Xn*Yn + a6*Xn*Yn
                    + a7*Xn*Yn*Yn + a8*Yn + a9*Yn*Yn + a10*Yn*Yn*Yn
             Yn+1 = a11 + a12*Xn + a13*Xn*Xn + a14 Xn*Xn*Xn + a15*Xn*Xn*Yn + a16*Xn*Yn
                    + a17*Xn*Yn*Yn + a18*Yn + a19*Yn*Yn + a20*Yn*Yn*Yn 
	            Aplicação cúbica bi-dimensional mais geral

Experimente os valores seguintes para os 20 parâmetros da aplicação cúbica: 
IRPGVTFIDGCSXMFPKIDJ, ISMHQCHPDFKFBKEALIFD, JYCBMNFNYOEPYUGHHESU,LGROKJFELDGKXSUEEWYE, MGGNDPHWONKFQUIIHBVP, NHZBEETDORVLAOTUPENH, NUYLCURDUHQUQMRZQWQB, OVFKWKEIBPGNYPVKWCYU.
Para a aplicação 2D quártica:
FUXRRRUIRDYKDUBPHHOMOBRIRBINCS, GNXVYVASWMMNFFQOFJTMRBNRFWREJH, LURFSRHWMSKHTQBKXJDXQSMFJBWUFG, PFMQPPBPARCUOLSTATEXQDKEXMLOIF, QDIDSBTPNDBSGOKOKGAKMCCONXFHWQ,RMJQBCSOAFMBRRSSUHCNBWVSRICXAA, TPMJKFSCWUMSHBVPCBUTBRRVXHSXIT,UETJGIINOTHGFYLJOUVEEMXTEGDHLM.
Para a aplicação 2D quíntica:
GEQGOYIKQQPEUJBKPXTVUSJHOVJDUAYYPRNTXFLGAM, VNTBSGWPIJIQFTJZIGRJTDXWLMDPWSVUNEFVSBMYFE
HVOIEGIDJCSFUFJCQGRUGMCLHEPWKRCCYFIRQPYAPH, MSMTNCONSQJOTKOPAOMQYNDPUQWVQJUEGNWAYGDLIT
QBKSKIXQMKEOVVMAHXLBOQQJXEYMBUMBOEFVDBAPWU, QDHFCNDPFVXOIXKPUMIQJJFOKCYELPTJPBSPOFGAPL
SARYDPNQIYYBGSXBFOFLRRPSWDEQGOSMSCONFEBVRP, VHDXLMSMKIBUMCNKOCPSPJMTFNPEDJQLNFOBTTHMPT.


REFERÊNCIAS
-----------

http://mathworld.wolfram.com/StrangeAttractor.html

Sprott, J. C. Strange Attractors: Creating Patterns in Chaos. New York: Henry Holt, 1993a. 
@#$#@#$#@
default
true
0
Polygon -7566196 true true 150 5 40 250 150 205 260 250

ant
true
0
Polygon -7566196 true true 136 61 129 46 144 30 119 45 124 60 114 82 97 37 132 10 93 36 111 84 127 105 172 105 189 84 208 35 171 11 202 35 204 37 186 82 177 60 180 44 159 32 170 44 165 60
Polygon -7566196 true true 150 95 135 103 139 117 125 149 137 180 135 196 150 204 166 195 161 180 174 150 158 116 164 102
Polygon -7566196 true true 149 186 128 197 114 232 134 270 149 282 166 270 185 232 171 195 149 186 149 186
Polygon -7566196 true true 225 66 230 107 159 122 161 127 234 111 236 106
Polygon -7566196 true true 78 58 99 116 139 123 137 128 95 119
Polygon -7566196 true true 48 103 90 147 129 147 130 151 86 151
Polygon -7566196 true true 65 224 92 171 134 160 135 164 95 175
Polygon -7566196 true true 235 222 210 170 163 162 161 166 208 174
Polygon -7566196 true true 249 107 211 147 168 147 168 150 213 150

arrow
true
0
Polygon -7566196 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

bee
true
0
Polygon -256 true false 152 149 77 163 67 195 67 211 74 234 85 252 100 264 116 276 134 286 151 300 167 285 182 278 206 260 220 242 226 218 226 195 222 166
Polygon -16777216 true false 150 149 128 151 114 151 98 145 80 122 80 103 81 83 95 67 117 58 141 54 151 53 177 55 195 66 207 82 211 94 211 116 204 139 189 149 171 152
Polygon -7566196 true true 151 54 119 59 96 60 81 50 78 39 87 25 103 18 115 23 121 13 150 1 180 14 189 23 197 17 210 19 222 30 222 44 212 57 192 58
Polygon -16777216 true false 70 185 74 171 223 172 224 186
Polygon -16777216 true false 67 211 71 226 224 226 225 211 67 211
Polygon -16777216 true false 91 257 106 269 195 269 211 255
Line -1 false 144 100 70 87
Line -1 false 70 87 45 87
Line -1 false 45 86 26 97
Line -1 false 26 96 22 115
Line -1 false 22 115 25 130
Line -1 false 26 131 37 141
Line -1 false 37 141 55 144
Line -1 false 55 143 143 101
Line -1 false 141 100 227 138
Line -1 false 227 138 241 137
Line -1 false 241 137 249 129
Line -1 false 249 129 254 110
Line -1 false 253 108 248 97
Line -1 false 249 95 235 82
Line -1 false 235 82 144 100

bird1
false
0
Polygon -7566196 true true 2 6 2 39 270 298 297 298 299 271 187 160 279 75 276 22 100 67 31 0

bird2
false
0
Polygon -7566196 true true 2 4 33 4 298 270 298 298 272 298 155 184 117 289 61 295 61 105 0 43

boat1
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 33 230 157 182 150 169 151 157 156
Polygon -7566196 true true 149 55 88 143 103 139 111 136 117 139 126 145 130 147 139 147 146 146 149 55

boat2
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 157 54 175 79 174 96 185 102 178 112 194 124 196 131 190 139 192 146 211 151 216 154 157 154
Polygon -7566196 true true 150 74 146 91 139 99 143 114 141 123 137 126 131 129 132 139 142 136 126 142 119 147 148 147

boat3
false
0
Polygon -1 true false 63 162 90 207 223 207 290 162
Rectangle -6524078 true false 150 32 157 162
Polygon -16776961 true false 150 34 131 49 145 47 147 48 149 49
Polygon -7566196 true true 158 37 172 45 188 59 202 79 217 109 220 130 218 147 204 156 158 156 161 142 170 123 170 102 169 88 165 62
Polygon -7566196 true true 149 66 142 78 139 96 141 111 146 139 148 147 110 147 113 131 118 106 126 71

box
true
0
Polygon -7566196 true true 45 255 255 255 255 45 45 45

butterfly1
true
0
Polygon -16777216 true false 151 76 138 91 138 284 150 296 162 286 162 91
Polygon -7566196 true true 164 106 184 79 205 61 236 48 259 53 279 86 287 119 289 158 278 177 256 182 164 181
Polygon -7566196 true true 136 110 119 82 110 71 85 61 59 48 36 56 17 88 6 115 2 147 15 178 134 178
Polygon -7566196 true true 46 181 28 227 50 255 77 273 112 283 135 274 135 180
Polygon -7566196 true true 165 185 254 184 272 224 255 251 236 267 191 283 164 276
Line -7566196 true 167 47 159 82
Line -7566196 true 136 47 145 81
Circle -7566196 true true 165 45 8
Circle -7566196 true true 134 45 6
Circle -7566196 true true 133 44 7
Circle -7566196 true true 133 43 8

circle
false
0
Circle -7566196 true true 35 35 230

person
false
0
Circle -7566196 true true 155 20 63
Rectangle -7566196 true true 158 79 217 164
Polygon -7566196 true true 158 81 110 129 131 143 158 109 165 110
Polygon -7566196 true true 216 83 267 123 248 143 215 107
Polygon -7566196 true true 167 163 145 234 183 234 183 163
Polygon -7566196 true true 195 163 195 233 227 233 206 159

sheep
false
15
Rectangle -1 true true 90 75 270 225
Circle -1 true true 15 75 150
Rectangle -16777216 true false 81 225 134 286
Rectangle -16777216 true false 180 225 238 285
Circle -16777216 true false 1 88 92

spacecraft
true
0
Polygon -7566196 true true 150 0 180 135 255 255 225 240 150 180 75 240 45 255 120 135

thin-arrow
true
0
Polygon -7566196 true true 150 0 0 150 120 150 120 293 180 293 180 150 300 150

truck-down
false
0
Polygon -7566196 true true 225 30 225 270 120 270 105 210 60 180 45 30 105 60 105 30
Polygon -8716033 true false 195 75 195 120 240 120 240 75
Polygon -8716033 true false 195 225 195 180 240 180 240 225

truck-left
false
0
Polygon -7566196 true true 120 135 225 135 225 210 75 210 75 165 105 165
Polygon -8716033 true false 90 210 105 225 120 210
Polygon -8716033 true false 180 210 195 225 210 210

truck-right
false
0
Polygon -7566196 true true 180 135 75 135 75 210 225 210 225 165 195 165
Polygon -8716033 true false 210 210 195 225 180 210
Polygon -8716033 true false 120 210 105 225 90 210

turtle
true
0
Polygon -7566196 true true 138 75 162 75 165 105 225 105 225 142 195 135 195 187 225 195 225 225 195 217 195 202 105 202 105 217 75 225 75 195 105 187 105 135 75 142 75 105 135 105

wolf
false
0
Rectangle -7566196 true true 15 105 105 165
Rectangle -7566196 true true 45 90 105 105
Polygon -7566196 true true 60 90 83 44 104 90
Polygon -16777216 true false 67 90 82 59 97 89
Rectangle -1 true false 48 93 59 105
Rectangle -16777216 true false 51 96 55 101
Rectangle -16777216 true false 0 121 15 135
Rectangle -16777216 true false 15 136 60 151
Polygon -1 true false 15 136 23 149 31 136
Polygon -1 true false 30 151 37 136 43 151
Rectangle -7566196 true true 105 120 263 195
Rectangle -7566196 true true 108 195 259 201
Rectangle -7566196 true true 114 201 252 210
Rectangle -7566196 true true 120 210 243 214
Rectangle -7566196 true true 115 114 255 120
Rectangle -7566196 true true 128 108 248 114
Rectangle -7566196 true true 150 105 225 108
Rectangle -7566196 true true 132 214 155 270
Rectangle -7566196 true true 110 260 132 270
Rectangle -7566196 true true 210 214 232 270
Rectangle -7566196 true true 189 260 210 270
Line -7566196 true 263 127 281 155
Line -7566196 true 281 155 281 192

wolf-left
false
3
Polygon -6524078 true true 117 97 91 74 66 74 60 85 36 85 38 92 44 97 62 97 81 117 84 134 92 147 109 152 136 144 174 144 174 103 143 103 134 97
Polygon -6524078 true true 87 80 79 55 76 79
Polygon -6524078 true true 81 75 70 58 73 82
Polygon -6524078 true true 99 131 76 152 76 163 96 182 104 182 109 173 102 167 99 173 87 159 104 140
Polygon -6524078 true true 107 138 107 186 98 190 99 196 112 196 115 190
Polygon -6524078 true true 116 140 114 189 105 137
Rectangle -6524078 true true 109 150 114 192
Rectangle -6524078 true true 111 143 116 191
Polygon -6524078 true true 168 106 184 98 205 98 218 115 218 137 186 164 196 176 195 194 178 195 178 183 188 183 169 164 173 144
Polygon -6524078 true true 207 140 200 163 206 175 207 192 193 189 192 177 198 176 185 150
Polygon -6524078 true true 214 134 203 168 192 148
Polygon -6524078 true true 204 151 203 176 193 148
Polygon -6524078 true true 207 103 221 98 236 101 243 115 243 128 256 142 239 143 233 133 225 115 214 114

wolf-right
false
3
Polygon -6524078 true true 170 127 200 93 231 93 237 103 262 103 261 113 253 119 231 119 215 143 213 160 208 173 189 187 169 190 154 190 126 180 106 171 72 171 73 126 122 126 144 123 159 123
Polygon -6524078 true true 201 99 214 69 215 99
Polygon -6524078 true true 207 98 223 71 220 101
Polygon -6524078 true true 184 172 189 234 203 238 203 246 187 247 180 239 171 180
Polygon -6524078 true true 197 174 204 220 218 224 219 234 201 232 195 225 179 179
Polygon -6524078 true true 78 167 95 187 95 208 79 220 92 234 98 235 100 249 81 246 76 241 61 212 65 195 52 170 45 150 44 128 55 121 69 121 81 135
Polygon -6524078 true true 48 143 58 141
Polygon -6524078 true true 46 136 68 137
Polygon -6524078 true true 45 129 35 142 37 159 53 192 47 210 62 238 80 237
Line -16777216 false 74 237 59 213
Line -16777216 false 59 213 59 212
Line -16777216 false 58 211 67 192
Polygon -6524078 true true 38 138 66 149
Polygon -6524078 true true 46 128 33 120 21 118 11 123 3 138 5 160 13 178 9 192 0 199 20 196 25 179 24 161 25 148 45 140
Polygon -6524078 true true 67 122 96 126 63 144

@#$#@#$#@
NetLogo 2.0.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@